You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 
 
 
 

910 lines
31 KiB

  1. AC_PREREQ(2.64)
  2. AC_INIT([openocd], [0.11.0+dev],
  3. [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
  4. AC_CONFIG_SRCDIR([src/openocd.c])
  5. AC_CONFIG_AUX_DIR([.])
  6. m4_include([config_subdir.m4])dnl
  7. # check for makeinfo before calling AM_INIT_AUTOMAKE
  8. AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  9. AS_IF([test "x$MAKEINFO" = "x"], [
  10. MAKEINFO='echo makeinfo missing; true'
  11. AC_MSG_WARN([Info documentation will not be built.])
  12. ])
  13. AC_SUBST([MAKEINFO])
  14. AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  15. AC_CONFIG_HEADERS([config.h])
  16. AH_BOTTOM([
  17. #include <helper/system.h>
  18. #include <helper/types.h>
  19. #include <helper/replacements.h>
  20. ])
  21. AC_LANG([C])
  22. AC_PROG_CC
  23. # autoconf 2.70 obsoletes AC_PROG_CC_C99 and includes it in AC_PROG_CC
  24. m4_version_prereq([2.70],[],[AC_PROG_CC_C99])
  25. AM_PROG_CC_C_O
  26. AC_PROG_RANLIB
  27. PKG_PROG_PKG_CONFIG([0.23])
  28. dnl disable checks for C++, Fortran and GNU Java Compiler
  29. m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  30. m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  31. m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  32. AC_DISABLE_SHARED
  33. LT_INIT
  34. AC_SUBST([LIBTOOL_DEPS])
  35. dnl configure checks required for Jim files (these are obsolete w/ C99)
  36. AC_C_CONST
  37. AC_TYPE_LONG_LONG_INT
  38. AC_SEARCH_LIBS([ioperm], [ioperm])
  39. AC_SEARCH_LIBS([dlopen], [dl])
  40. AC_SEARCH_LIBS([openpty], [util])
  41. AC_CHECK_HEADERS([sys/socket.h])
  42. AC_CHECK_HEADERS([elf.h])
  43. AC_CHECK_HEADERS([dirent.h])
  44. AC_CHECK_HEADERS([fcntl.h])
  45. AC_CHECK_HEADERS([malloc.h])
  46. AC_CHECK_HEADERS([netdb.h])
  47. AC_CHECK_HEADERS([poll.h])
  48. AC_CHECK_HEADERS([pthread.h])
  49. AC_CHECK_HEADERS([strings.h])
  50. AC_CHECK_HEADERS([sys/ioctl.h])
  51. AC_CHECK_HEADERS([sys/param.h])
  52. AC_CHECK_HEADERS([sys/select.h])
  53. AC_CHECK_HEADERS([sys/stat.h])
  54. AC_CHECK_HEADERS([sys/sysctl.h])
  55. AC_CHECK_HEADERS([sys/time.h])
  56. AC_CHECK_HEADERS([sys/types.h])
  57. AC_CHECK_HEADERS([unistd.h])
  58. AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
  59. #include <stdio.h>
  60. #ifdef STDC_HEADERS
  61. # include <stdlib.h>
  62. # include <stddef.h>
  63. #else
  64. # ifdef HAVE_STDLIB_H
  65. # include <stdlib.h>
  66. # endif
  67. #endif
  68. #ifdef HAVE_SYS_SOCKET_H
  69. # include <sys/socket.h>
  70. #endif
  71. ])
  72. AC_HEADER_ASSERT
  73. AC_HEADER_STDBOOL
  74. AC_C_BIGENDIAN
  75. AC_CHECK_FUNCS([strndup])
  76. AC_CHECK_FUNCS([strnlen])
  77. AC_CHECK_FUNCS([gettimeofday])
  78. AC_CHECK_FUNCS([usleep])
  79. AC_CHECK_FUNCS([vasprintf])
  80. AC_CHECK_FUNCS([realpath])
  81. # guess-rev.sh only exists in the repository, not in the released archives
  82. AC_MSG_CHECKING([whether to build a release])
  83. AS_IF([test -x "$srcdir/guess-rev.sh"], [
  84. build_release=no
  85. ], [
  86. build_release=yes
  87. ])
  88. AC_MSG_RESULT([$build_release])
  89. # Adapter drivers
  90. # 1st column -- configure option
  91. # 2nd column -- description
  92. # 3rd column -- symbol used for both config.h and automake
  93. m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
  94. m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
  95. m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
  96. m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
  97. m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
  98. m4_define([USB1_ADAPTERS],
  99. [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
  100. [[stlink], [ST-Link Programmer], [HLADAPTER_STLINK]],
  101. [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
  102. [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
  103. [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
  104. [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
  105. [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]],
  106. [[xds110], [TI XDS110 Debug Probe], [XDS110]],
  107. [[cmsis_dap_v2], [CMSIS-DAP v2 Compliant Debugger], [CMSIS_DAP_USB]],
  108. [[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
  109. [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
  110. [[aice], [Andes JTAG Programmer], [AICE]]])
  111. m4_define([USB0_ADAPTERS],
  112. [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
  113. [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
  114. [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
  115. m4_define([HIDAPI_ADAPTERS],
  116. [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP_HID]],
  117. [[nulink], [Nu-Link Programmer], [HLADAPTER_NULINK]]])
  118. m4_define([HIDAPI_USB1_ADAPTERS],
  119. [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
  120. m4_define([LIBFTDI_ADAPTERS],
  121. [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
  122. [[presto], [ASIX Presto Adapter], [PRESTO]]])
  123. m4_define([LIBFTDI_USB1_ADAPTERS],
  124. [[[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
  125. m4_define([LIBGPIOD_ADAPTERS],
  126. [[[linuxgpiod], [Linux GPIO bitbang through libgpiod], [LINUXGPIOD]]])
  127. m4_define([LIBJAYLINK_ADAPTERS],
  128. [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
  129. m4_define([PCIE_ADAPTERS],
  130. [[[xlnx_pcie_xvc], [Xilinx XVC/PCIe], [XLNX_PCIE_XVC]]])
  131. m4_define([OPTIONAL_LIBRARIES],
  132. [[[capstone], [Use Capstone disassembly framework], []]])
  133. AC_ARG_ENABLE([doxygen-html],
  134. AS_HELP_STRING([--disable-doxygen-html],
  135. [Disable building Doxygen manual as HTML.]),
  136. [doxygen_as_html=$enableval], [doxygen_as_html=yes])
  137. AC_SUBST([doxygen_as_html])
  138. AC_MSG_CHECKING([whether to build Doxygen as HTML])
  139. AC_MSG_RESULT([$doxygen_as_html])
  140. AC_ARG_ENABLE([doxygen-pdf],
  141. AS_HELP_STRING([--enable-doxygen-pdf],
  142. [Enable building Doxygen manual as PDF.]),
  143. [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
  144. AC_SUBST([doxygen_as_pdf])
  145. AC_MSG_CHECKING([whether to build Doxygen as PDF])
  146. AC_MSG_RESULT([$doxygen_as_pdf])
  147. AC_ARG_ENABLE([gccwarnings],
  148. AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
  149. [gcc_warnings=$enableval], [gcc_warnings=yes])
  150. AC_ARG_ENABLE([wextra],
  151. AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
  152. [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
  153. AC_ARG_ENABLE([werror],
  154. AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
  155. [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
  156. # set default verbose options, overridden by following options
  157. debug_usb_io=no
  158. debug_usb_comms=no
  159. AC_ARG_ENABLE([verbose],
  160. AS_HELP_STRING([--enable-verbose],
  161. [Enable verbose JTAG I/O messages (for debugging).]),
  162. [
  163. debug_usb_io=$enableval
  164. debug_usb_comms=$enableval
  165. ], [])
  166. AC_ARG_ENABLE([verbose_usb_io],
  167. AS_HELP_STRING([--enable-verbose-usb-io],
  168. [Enable verbose USB I/O messages (for debugging)]),
  169. [debug_usb_io=$enableval], [])
  170. AC_ARG_ENABLE([verbose_usb_comms],
  171. AS_HELP_STRING([--enable-verbose-usb-comms],
  172. [Enable verbose USB communication messages (for debugging)]),
  173. [debug_usb_comms=$enableval], [])
  174. AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
  175. AC_MSG_RESULT([$debug_usb_io])
  176. AS_IF([test "x$debug_usb_io" = "xyes"], [
  177. AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
  178. ])
  179. AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
  180. AC_MSG_RESULT([$debug_usb_comms])
  181. AS_IF([test "x$debug_usb_comms" = "xyes"], [
  182. AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
  183. ])
  184. debug_malloc=no
  185. AC_ARG_ENABLE([malloc_logging],
  186. AS_HELP_STRING([--enable-malloc-logging],
  187. [Include free space in logging messages (requires malloc.h).]),
  188. [debug_malloc=$enableval], [])
  189. AC_MSG_CHECKING([whether to enable malloc free space logging]);
  190. AC_MSG_RESULT([$debug_malloc])
  191. AS_IF([test "x$debug_malloc" = "xyes"], [
  192. AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
  193. ])
  194. AC_ARG_ENABLE([dummy],
  195. AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
  196. [build_dummy=$enableval], [build_dummy=no])
  197. AC_ARG_ENABLE([rshim],
  198. AS_HELP_STRING([--enable-rshim], [Enable building the rshim driver]),
  199. [build_rshim=$enableval], [build_rshim=no])
  200. m4_define([AC_ARG_ADAPTERS], [
  201. m4_foreach([adapter], [$1],
  202. [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
  203. AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
  204. [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
  205. [], [ADAPTER_VAR([adapter])=$2])
  206. ])
  207. ])
  208. AC_ARG_ADAPTERS([
  209. USB1_ADAPTERS,
  210. USB0_ADAPTERS,
  211. HIDAPI_ADAPTERS,
  212. HIDAPI_USB1_ADAPTERS,
  213. LIBFTDI_ADAPTERS,
  214. LIBFTDI_USB1_ADAPTERS
  215. LIBGPIOD_ADAPTERS,
  216. LIBJAYLINK_ADAPTERS
  217. ],[auto])
  218. AC_ARG_ENABLE([parport],
  219. AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
  220. [build_parport=$enableval], [build_parport=no])
  221. AC_ARG_ENABLE([parport_ppdev],
  222. AS_HELP_STRING([--disable-parport-ppdev],
  223. [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
  224. [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
  225. AC_ARG_ENABLE([parport_giveio],
  226. AS_HELP_STRING([--enable-parport-giveio],
  227. [Enable use of giveio for parport (for CygWin only)]),
  228. [parport_use_giveio=$enableval], [parport_use_giveio=])
  229. AC_ARG_ENABLE([jtag_vpi],
  230. AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
  231. [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
  232. AC_ARG_ENABLE([jtag_dpi],
  233. AS_HELP_STRING([--enable-jtag_dpi], [Enable building support for JTAG DPI]),
  234. [build_jtag_dpi=$enableval], [build_jtag_dpi=no])
  235. AC_ARG_ENABLE([amtjtagaccel],
  236. AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
  237. [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
  238. AC_ARG_ENABLE([zy1000_master],
  239. AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
  240. [build_zy1000_master=$enableval], [build_zy1000_master=no])
  241. AC_ARG_ENABLE([zy1000],
  242. AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
  243. [build_zy1000=$enableval], [build_zy1000=no])
  244. AC_ARG_ENABLE([ioutil],
  245. AS_HELP_STRING([--enable-ioutil], [Enable ioutil functions - useful for standalone OpenOCD implementations]),
  246. [build_ioutil=$enableval], [build_ioutil=no])
  247. AS_CASE(["${host_cpu}"],
  248. [arm*|aarch64], [
  249. AC_ARG_ENABLE([bcm2835gpio],
  250. AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
  251. [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
  252. AC_ARG_ENABLE([imx_gpio],
  253. AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
  254. [build_imx_gpio=$enableval], [build_imx_gpio=no])
  255. ],
  256. [
  257. build_bcm2835gpio=no
  258. build_imx_gpio=no
  259. ])
  260. AS_CASE(["${host_cpu}"],
  261. [arm*], [
  262. AC_ARG_ENABLE([ep93xx],
  263. AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
  264. [build_ep93xx=$enableval], [build_ep93xx=no])
  265. AC_ARG_ENABLE([at91rm9200],
  266. AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
  267. [build_at91rm9200=$enableval], [build_at91rm9200=no])
  268. ],
  269. [
  270. build_ep93xx=no
  271. build_at91rm9200=no
  272. ])
  273. AC_ARG_ENABLE([gw16012],
  274. AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
  275. [build_gw16012=$enableval], [build_gw16012=no])
  276. AC_ARG_ENABLE([oocd_trace],
  277. AS_HELP_STRING([--enable-oocd_trace],
  278. [Enable building support for some prototype OpenOCD+trace ETM capture hardware]),
  279. [build_oocd_trace=$enableval], [build_oocd_trace=no])
  280. AC_ARG_ENABLE([buspirate],
  281. AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
  282. [build_buspirate=$enableval], [build_buspirate=no])
  283. AC_ARG_ENABLE([sysfsgpio],
  284. AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
  285. [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
  286. AC_ARG_ENABLE([xlnx_pcie_xvc],
  287. AS_HELP_STRING([--enable-xlnx-pcie-xvc], [Enable building support for Xilinx XVC/PCIe.]),
  288. [build_xlnx_pcie_xvc=$enableval], [build_xlnx_pcie_xvc=no])
  289. AS_CASE([$host_os],
  290. [linux*], [],
  291. [
  292. AS_IF([test "x$build_sysfsgpio" = "xyes"], [
  293. AC_MSG_ERROR([sysfsgpio is only available on linux])
  294. ])
  295. AS_IF([test "x$enable_linuxgpiod" = "xyes"], [
  296. AC_MSG_ERROR([linuxgpiod is only available on linux])
  297. ])
  298. AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
  299. AC_MSG_ERROR([xlnx_pcie_xvc is only available on linux])
  300. ])
  301. AS_CASE([$host_os], [freebsd*], [],
  302. [
  303. AS_IF([test "x$build_rshim" = "xyes"], [
  304. AC_MSG_ERROR([build_rshim is only available on linux or freebsd])
  305. ])
  306. ])
  307. ])
  308. AC_ARG_ENABLE([minidriver_dummy],
  309. AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
  310. [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
  311. AC_ARG_ENABLE([internal-jimtcl],
  312. AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
  313. [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
  314. AC_ARG_ENABLE([internal-libjaylink],
  315. AS_HELP_STRING([--disable-internal-libjaylink],
  316. [Disable building internal libjaylink]),
  317. [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
  318. build_minidriver=no
  319. AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
  320. AS_IF([test "x$build_zy1000" = "xyes"], [
  321. AS_IF([test "x$build_minidriver" = "xyes"], [
  322. AC_MSG_ERROR([Multiple minidriver options have been enabled.])
  323. ])
  324. AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
  325. [Define to 1 if you have the <jtag_minidriver.h> header file.])
  326. build_minidriver=yes
  327. ])
  328. AC_MSG_RESULT([$build_zy1000])
  329. AC_ARG_ENABLE([remote-bitbang],
  330. AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
  331. [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
  332. AC_MSG_CHECKING([whether to enable dummy minidriver])
  333. AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
  334. AS_IF([test "x$build_minidriver" = "xyes"], [
  335. AC_MSG_ERROR([Multiple minidriver options have been enabled.])
  336. ])
  337. build_minidriver=yes
  338. AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
  339. AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
  340. [Define to 1 if you have the <jtag_minidriver.h> header file.])
  341. ])
  342. AC_MSG_RESULT([$build_minidriver_dummy])
  343. AC_MSG_CHECKING([whether standard drivers can be built])
  344. AS_IF([test "x$build_minidriver" = "xyes"], [
  345. AC_MSG_RESULT([no])
  346. AC_MSG_WARN([Using the minidriver disables all other drivers.])
  347. sleep 2
  348. ], [
  349. AC_MSG_RESULT([yes])
  350. ])
  351. AS_CASE(["${host_cpu}"],
  352. [i?86|x86*], [],
  353. [
  354. AS_IF([test "x$parport_use_ppdev" = "xno"], [
  355. AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
  356. ])
  357. parport_use_ppdev=yes
  358. ])
  359. AS_CASE([$host],
  360. [*-cygwin*], [
  361. is_win32=yes
  362. parport_use_ppdev=no
  363. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
  364. [is_mingw=yes],[is_mingw=no])
  365. AS_IF([test "x$is_mingw" = "xyes"], [
  366. AS_IF([test "x$parport_use_giveio" = "xno"], [
  367. AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
  368. ])
  369. parport_use_giveio=yes
  370. is_cygwin=no
  371. ], [
  372. is_cygwin=yes
  373. # sys/io.h needed under cygwin for parport access
  374. AS_IF([test "x$build_parport" = "xyes"], [
  375. AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
  376. ])
  377. ])
  378. ],
  379. [*-mingw* | *-msys*], [
  380. is_mingw=yes
  381. is_win32=yes
  382. parport_use_ppdev=no
  383. AS_IF([test "x$parport_use_giveio" = "xno"], [
  384. AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
  385. ])
  386. parport_use_giveio=yes
  387. AS_IF([test "x$build_buspirate" = "xyes"], [
  388. AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
  389. ])
  390. AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
  391. ],
  392. [*darwin*], [
  393. is_darwin=yes
  394. AS_IF([test "x$parport_use_giveio" = "xyes"], [
  395. AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
  396. ])
  397. parport_use_giveio=no
  398. ],
  399. [
  400. AS_IF([test "x$parport_use_giveio" = "xyes"], [
  401. AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
  402. ])
  403. parport_use_giveio=no
  404. ])
  405. AS_IF([test "x$is_cygwin" = "xyes"], [
  406. AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
  407. ], [
  408. AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
  409. ])
  410. AS_IF([test "x$is_mingw" = "xyes"], [
  411. AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
  412. ], [
  413. AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
  414. ])
  415. AS_IF([test "x$is_win32" = "xyes"], [
  416. AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
  417. ], [
  418. AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
  419. ])
  420. AS_IF([test "x$is_darwin" = "xyes"], [
  421. AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
  422. ], [
  423. AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
  424. ])
  425. AS_IF([test "x$build_parport" = "xyes"], [
  426. build_bitbang=yes
  427. AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
  428. ], [
  429. AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
  430. ])
  431. AS_IF([test "x$build_rshim" = "xyes"], [
  432. AC_DEFINE([BUILD_RSHIM], [1], [1 if you want to debug BlueField SoC via rshim.])
  433. ], [
  434. AC_DEFINE([BUILD_RSHIM], [0], [0 if you don't want to debug BlueField SoC via rshim.])
  435. ])
  436. AS_IF([test "x$build_dummy" = "xyes"], [
  437. build_bitbang=yes
  438. AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
  439. ], [
  440. AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
  441. ])
  442. AS_IF([test "x$build_ep93xx" = "xyes"], [
  443. build_bitbang=yes
  444. AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
  445. ], [
  446. AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
  447. ])
  448. AS_IF([test "x$build_zy1000" = "xyes"], [
  449. AC_DEFINE([BUILD_ZY1000], [1], [1 if you want ZY1000.])
  450. ], [
  451. AC_DEFINE([BUILD_ZY1000], [0], [0 if you don't want ZY1000.])
  452. ])
  453. AS_IF([test "x$build_zy1000_master" = "xyes"], [
  454. AC_DEFINE([BUILD_ZY1000_MASTER], [1], [1 if you want ZY1000 JTAG master registers.])
  455. ], [
  456. AC_DEFINE([BUILD_ZY1000_MASTER], [0], [0 if you don't want ZY1000 JTAG master registers.])
  457. ])
  458. AS_IF([test "x$build_at91rm9200" = "xyes"], [
  459. build_bitbang=yes
  460. AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
  461. ], [
  462. AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
  463. ])
  464. AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
  465. build_bitbang=yes
  466. AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
  467. ], [
  468. AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
  469. ])
  470. AS_IF([test "x$build_imx_gpio" = "xyes"], [
  471. build_bitbang=yes
  472. AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
  473. ], [
  474. AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
  475. ])
  476. AS_IF([test "x$parport_use_ppdev" = "xyes"], [
  477. AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
  478. ], [
  479. AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
  480. ])
  481. AS_IF([test "x$parport_use_giveio" = "xyes"], [
  482. AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
  483. ], [
  484. AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
  485. ])
  486. AS_IF([test "x$build_jtag_vpi" = "xyes"], [
  487. AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
  488. ], [
  489. AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
  490. ])
  491. AS_IF([test "x$build_jtag_dpi" = "xyes"], [
  492. AC_DEFINE([BUILD_JTAG_DPI], [1], [1 if you want JTAG DPI.])
  493. ], [
  494. AC_DEFINE([BUILD_JTAG_DPI], [0], [0 if you don't want JTAG DPI.])
  495. ])
  496. AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
  497. AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
  498. ], [
  499. AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
  500. ])
  501. AS_IF([test "x$build_gw16012" = "xyes"], [
  502. AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
  503. ], [
  504. AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
  505. ])
  506. AS_IF([test "x$build_oocd_trace" = "xyes"], [
  507. AC_DEFINE([BUILD_OOCD_TRACE], [1], [1 if you want the OpenOCD+trace ETM capture driver.])
  508. ], [
  509. AC_DEFINE([BUILD_OOCD_TRACE], [0], [0 if you don't want the OpenOCD+trace ETM capture driver.])
  510. ])
  511. AS_IF([test "x$build_buspirate" = "xyes"], [
  512. AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
  513. ], [
  514. AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
  515. ])
  516. AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
  517. AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
  518. AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
  519. ], [
  520. AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
  521. ])
  522. ])
  523. AS_IF([test "x$build_remote_bitbang" = "xyes"], [
  524. build_bitbang=yes
  525. AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
  526. ], [
  527. AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
  528. ])
  529. AS_IF([test "x$build_sysfsgpio" = "xyes"], [
  530. build_bitbang=yes
  531. AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
  532. ], [
  533. AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
  534. ])
  535. AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
  536. build_xlnx_pcie_xvc=yes
  537. AC_DEFINE([BUILD_XLNX_PCIE_XVC], [1], [1 if you want the Xilinx XVC/PCIe driver.])
  538. ], [
  539. AC_DEFINE([BUILD_XLNX_PCIE_XVC], [0], [0 if you don't want Xilinx XVC/PCIe driver.])
  540. ])
  541. PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
  542. use_libusb1=yes
  543. AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
  544. PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
  545. [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
  546. [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
  547. LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
  548. AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
  549. PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
  550. [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
  551. ], [
  552. use_libusb1=no
  553. AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
  554. ])
  555. PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
  556. AC_ARG_WITH([capstone],
  557. AS_HELP_STRING([--with-capstone], [Use Capstone disassembly library (default=auto)])
  558. , [
  559. enable_capstone=$withval
  560. ], [
  561. enable_capstone=auto
  562. ])
  563. AS_IF([test "x$enable_capstone" != xno], [
  564. PKG_CHECK_MODULES([CAPSTONE], [capstone], [
  565. AC_DEFINE([HAVE_CAPSTONE], [1], [1 if you have Capstone disassembly framework.])
  566. ], [
  567. AC_DEFINE([HAVE_CAPSTONE], [0], [0 if you don't have Capstone disassembly framework.])
  568. if test "x$enable_capstone" != xauto; then
  569. AC_MSG_ERROR([--with-capstone was given, but test for Capstone failed])
  570. fi
  571. enable_capstone=no
  572. ])
  573. ])
  574. for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
  575. PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
  576. use_hidapi=yes
  577. break
  578. ],[
  579. use_hidapi=no
  580. ])
  581. done
  582. PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [
  583. use_libftdi=yes
  584. PKG_CHECK_EXISTS([libftdi1 >= 1.5],
  585. [AC_DEFINE([HAVE_LIBFTDI_TCIOFLUSH], [1], [Define if your libftdi has ftdi_tcioflush()])])
  586. ], [
  587. PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
  588. ])
  589. PKG_CHECK_MODULES([LIBGPIOD], [libgpiod], [use_libgpiod=yes], [use_libgpiod=no])
  590. PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
  591. [use_libjaylink=yes], [use_libjaylink=no])
  592. m4_define([PROCESS_ADAPTERS], [
  593. m4_foreach([adapter], [$1], [
  594. AS_IF([test "x$build_zy1000" = "xyes"], [
  595. ADAPTER_VAR([adapter])=no
  596. ])
  597. AS_IF([test $2], [
  598. AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
  599. AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
  600. ], [
  601. AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
  602. ])
  603. ], [
  604. AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
  605. AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
  606. ])
  607. ADAPTER_VAR([adapter])=no
  608. ])
  609. AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
  610. ])
  611. ])
  612. PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
  613. PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
  614. PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
  615. PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
  616. PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
  617. PROCESS_ADAPTERS([LIBFTDI_USB1_ADAPTERS], ["x$use_libftdi" = "xyes" -a "x$use_libusb1" = "xyes"], [libftdi and libusb-1.x])
  618. PROCESS_ADAPTERS([LIBGPIOD_ADAPTERS], ["x$use_libgpiod" = "xyes"], [libgpiod])
  619. PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.2])
  620. AS_IF([test "x$enable_linuxgpiod" != "xno"], [
  621. build_bitbang=yes
  622. ])
  623. AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno" -o "x$enable_nulink" != "xno"], [
  624. AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
  625. AM_CONDITIONAL([HLADAPTER], [true])
  626. ], [
  627. AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
  628. AM_CONDITIONAL([HLADAPTER], [false])
  629. ])
  630. AM_CONDITIONAL([HLADAPTER_STLINK], [test "x$enable_stlink" != "xno"])
  631. AM_CONDITIONAL([HLADAPTER_ICDI], [test "x$enable_ti_icdi" != "xno"])
  632. AM_CONDITIONAL([HLADAPTER_NULINK], [test "x$enable_nulink" != "xno"])
  633. AS_IF([test "x$enable_jlink" != "xno"], [
  634. AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
  635. AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
  636. AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
  637. [--enable-subproject-build])
  638. ], [
  639. AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
  640. ])
  641. ])
  642. ])
  643. # Presto needs the bitq module
  644. AS_IF([test "x$enable_presto" != "xno"], [
  645. build_bitq=yes
  646. ])
  647. AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
  648. AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
  649. AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
  650. AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
  651. AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
  652. AM_CONDITIONAL([ZY1000], [test "x$build_zy1000" = "xyes"])
  653. AM_CONDITIONAL([ZY1000_MASTER], [test "x$build_zy1000_master" = "xyes"])
  654. AM_CONDITIONAL([IOUTIL], [test "x$build_ioutil" = "xyes"])
  655. AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
  656. AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
  657. AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
  658. AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
  659. AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
  660. AM_CONDITIONAL([JTAG_DPI], [test "x$build_jtag_dpi" = "xyes" -o "x$build_jtag_dpi" = "xyes"])
  661. AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
  662. AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
  663. AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
  664. AM_CONDITIONAL([OOCD_TRACE], [test "x$build_oocd_trace" = "xyes"])
  665. AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
  666. AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
  667. AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
  668. AM_CONDITIONAL([XLNX_PCIE_XVC], [test "x$build_xlnx_pcie_xvc" = "xyes"])
  669. AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
  670. AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
  671. AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
  672. AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
  673. AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
  674. AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
  675. AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
  676. AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
  677. AM_CONDITIONAL([USE_LIBGPIOD], [test "x$use_libgpiod" = "xyes"])
  678. AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
  679. AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
  680. AM_CONDITIONAL([RSHIM], [test "x$build_rshim" = "xyes"])
  681. AM_CONDITIONAL([HAVE_CAPSTONE], [test "x$enable_capstone" != "xno"])
  682. AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
  683. AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
  684. AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
  685. AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
  686. # Look for environ alternatives. Possibility #1: is environ in unistd.h or stdlib.h?
  687. AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
  688. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  689. #define _GNU_SOURCE
  690. #include <unistd.h>
  691. #include <stdlib.h>
  692. ]], [[char **ep = environ;]]
  693. )], [
  694. AC_MSG_RESULT([yes])
  695. has_environ=yes
  696. ], [
  697. AC_MSG_RESULT([no])
  698. # Possibility #2: can environ be found in an available library?
  699. AC_MSG_CHECKING([for extern environ])
  700. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  701. extern char **environ;
  702. ]], [[char **ep = environ;]]
  703. )], [
  704. AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
  705. has_environ=yes
  706. ], [
  707. has_environ=no
  708. ])
  709. AC_MSG_RESULT([${has_environ}])
  710. ])
  711. AS_IF([test "x${has_environ}" != "xyes" ], [
  712. AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
  713. ])
  714. AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
  715. # set default gcc warnings
  716. GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
  717. AS_IF([test "x${gcc_wextra}" = "xyes"], [
  718. GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
  719. GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
  720. GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
  721. GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
  722. GCC_WARNINGS="${GCC_WARNINGS} -Wpointer-arith"
  723. ])
  724. AS_IF([test "x${gcc_werror}" = "xyes"], [
  725. GCC_WARNINGS="${GCC_WARNINGS} -Werror"
  726. ])
  727. # override default gcc cflags
  728. AS_IF([test "x$gcc_warnings" = "xyes"], [
  729. AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
  730. ])
  731. AC_SUBST(EXTRA_DIST_NEWS, ["$(echo $srcdir/NEWS-*)"])
  732. AC_CONFIG_FILES([
  733. Makefile
  734. ])
  735. AC_OUTPUT
  736. echo
  737. echo
  738. echo OpenOCD configuration summary
  739. echo --------------------------------------------------
  740. m4_foreach([adapter], [USB1_ADAPTERS, USB0_ADAPTERS,
  741. HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
  742. LIBFTDI_USB1_ADAPTERS,
  743. LIBGPIOD_ADAPTERS,
  744. LIBJAYLINK_ADAPTERS, PCIE_ADAPTERS,
  745. OPTIONAL_LIBRARIES],
  746. [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
  747. AS_CASE([$ADAPTER_VAR([adapter])],
  748. [auto], [
  749. echo "$s"yes '(auto)'
  750. ],
  751. [yes], [
  752. echo "$s"yes
  753. ],
  754. [no], [
  755. echo "$s"no
  756. ])
  757. ])
  758. echo
  759. AS_IF([test "x$build_oocd_trace" = "xyes"], [
  760. echo 'WARNING! Deprecated configure option (--enable-oocd_trace)'
  761. echo 'The oocd_trace driver is deprecated and will be removed in the next release.'
  762. echo 'If you regularly use this driver, please report to the OpenOCD Mailing List.'
  763. echo
  764. ])
  765. AS_IF([test "x$build_zy1000" = "xyes" -o "x$build_zy1000_master" = "xyes"], [
  766. echo 'WARNING! Deprecated configure option (--enable-zy1000, --enable-zy1000-master)'
  767. echo 'Support for the ZY1000 platform is deprecated and will be removed in the next'
  768. echo 'release. If you regularly use this platform, please report to the OpenOCD'
  769. echo 'Mailing List.'
  770. echo
  771. ])
  772. AS_IF([test "x$build_ioutil" = "xyes"], [
  773. echo 'WARNING! Deprecated configure option (--enable-ioutil)'
  774. echo 'Support for the ioutil functions is deprecated and will be removed in the next'
  775. echo 'release. If you regularly depend on this functionality, please report to the'
  776. echo 'OpenOCD Mailing List.'
  777. echo
  778. ])