You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 
 
 
 

126 lines
3.6 KiB

  1. /***************************************************************************
  2. * Copyright (C) 2011 by Andreas Fritiofson *
  3. * andreas.fritiofson@gmail.com *
  4. * *
  5. * Copyright (C) 2013 by Paul Fertser *
  6. * fercerpav@gmail.com *
  7. * *
  8. * This program is free software; you can redistribute it and/or modify *
  9. * it under the terms of the GNU General Public License as published by *
  10. * the Free Software Foundation; either version 2 of the License, or *
  11. * (at your option) any later version. *
  12. * *
  13. * This program is distributed in the hope that it will be useful, *
  14. * but WITHOUT ANY WARRANTY; without even the implied warranty of *
  15. * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the *
  16. * GNU General Public License for more details. *
  17. * *
  18. * You should have received a copy of the GNU General Public License *
  19. * along with this program; if not, write to the *
  20. * Free Software Foundation, Inc., *
  21. * 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA. *
  22. ***************************************************************************/
  23. .text
  24. .syntax unified
  25. .cpu cortex-m0
  26. .thumb
  27. .thumb_func
  28. .global write
  29. /* Params:
  30. * r0 - flash base (in), status (out)
  31. * r1 - count (32bit)
  32. * r2 - workarea start
  33. * r3 - workarea end
  34. * r4 - target address
  35. * Clobbered:
  36. * r5 - rp
  37. * r6 - wp, tmp
  38. * r7 - current FLASH_CMD
  39. */
  40. #define FLASH_CMD 0x00
  41. #define FLASH_ADR 0x04
  42. #define FLASH_DI 0x08
  43. #define FLASH_NVSTR (1 << 13)
  44. #define FLASH_PROG (1 << 12)
  45. #define FLASH_MAS1 (1 << 11)
  46. #define FLASH_ERASE (1 << 10)
  47. #define FLASH_SE (1 << 8)
  48. #define FLASH_YE (1 << 7)
  49. #define FLASH_XE (1 << 6)
  50. ldr r7, [r0, #FLASH_CMD]
  51. wait_fifo:
  52. ldr r6, [r2, #0] /* read wp */
  53. cmp r6, #0 /* abort if wp == 0 */
  54. beq exit
  55. ldr r5, [r2, #4] /* read rp */
  56. cmp r5, r6 /* wait until rp != wp */
  57. beq wait_fifo
  58. ldr r6, [r5] /* "*target_address++ = *rp++" */
  59. str r4, [r0, #FLASH_ADR]
  60. str r6, [r0, #FLASH_DI]
  61. ldr r6, =(FLASH_XE | FLASH_PROG)
  62. orrs r7, r7, r6
  63. str r7, [r0, #FLASH_CMD]
  64. # wait 5us
  65. movs r6, #5
  66. bl delay
  67. ldr r6, =#FLASH_NVSTR
  68. orrs r7, r7, r6
  69. str r7, [r0, #FLASH_CMD]
  70. # wait 10us
  71. movs r6, #13
  72. bl delay
  73. movs r6, #FLASH_YE
  74. orrs r7, r7, r6
  75. str r7, [r0, #FLASH_CMD]
  76. # wait 40us
  77. movs r6, #61
  78. bl delay
  79. movs r6, #FLASH_YE
  80. bics r7, r7, r6
  81. str r7, [r0, #FLASH_CMD]
  82. ldr r6, =#FLASH_PROG
  83. bics r7, r7, r6
  84. str r7, [r0, #FLASH_CMD]
  85. # wait 5us
  86. movs r6, #5
  87. bl delay
  88. ldr r6, =#(FLASH_XE | FLASH_NVSTR)
  89. bics r7, r7, r6
  90. str r7, [r0, #FLASH_CMD]
  91. adds r5, #4
  92. adds r4, #4
  93. cmp r5, r3 /* wrap rp at end of buffer */
  94. bcc no_wrap
  95. mov r5, r2
  96. adds r5, #8
  97. no_wrap:
  98. str r5, [r2, #4] /* store rp */
  99. subs r1, r1, #1 /* decrement word count */
  100. cmp r1, #0
  101. beq exit /* loop if not done */
  102. b wait_fifo
  103. exit:
  104. mov r0, r6 /* return status in r0 */
  105. bkpt #0
  106. /* r6 - in
  107. * for r6 == 1 it'll take:
  108. * 1 (prepare operand) + 4 (bl) + 2 (subs+cmp) + 1 (bne) + 3 (b) ->
  109. * 11 tacts == 1.4us with 8MHz
  110. * every extra iteration will take 5 tacts == 0.6us */
  111. delay:
  112. subs r6, r6, #1
  113. cmp r6, #0
  114. bne delay
  115. bx lr