You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 
 
 
 

1212 lines
37 KiB

  1. AC_PREREQ(2.60)
  2. AC_INIT([openocd], [0.6.0-dev],
  3. [OpenOCD Mailing List <openocd-development@lists.berlios.de>])
  4. AC_CONFIG_SRCDIR([src/openocd.c])
  5. m4_include(config_subdir.m4)dnl
  6. AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip])
  7. AM_MAINTAINER_MODE
  8. AM_CONFIG_HEADER(config.h)
  9. AH_BOTTOM([
  10. #include <helper/system.h>
  11. #include <helper/replacements.h>
  12. ])
  13. AC_LANG_C
  14. AC_PROG_CC
  15. AC_PROG_CC_C99
  16. AM_PROG_CC_C_O
  17. AC_PROG_RANLIB
  18. dnl disable checks for C++, Fortran and GNU Java Compiler
  19. m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  20. m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  21. m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  22. AC_DISABLE_SHARED
  23. AC_PROG_LIBTOOL
  24. AC_SUBST(LIBTOOL_DEPS)
  25. dnl configure checks required for Jim files (these are obsolete w/ C99)
  26. AC_C_CONST
  27. AC_TYPE_LONG_LONG_INT
  28. AC_SEARCH_LIBS([ioperm], [ioperm])
  29. AC_SEARCH_LIBS([dlopen], [dl])
  30. AC_CHECK_HEADERS(sys/socket.h)
  31. AC_CHECK_HEADERS(arpa/inet.h, [], [], [dnl
  32. #include <stdio.h>
  33. #ifdef STDC_HEADERS
  34. # include <stdlib.h>
  35. # include <stddef.h>
  36. #else
  37. # ifdef HAVE_STDLIB_H
  38. # include <stdlib.h>
  39. # endif
  40. #endif
  41. #ifdef HAVE_SYS_SOCKET_H
  42. # include <sys/socket.h>
  43. #endif
  44. ])
  45. AC_CHECK_HEADERS(elf.h)
  46. AC_CHECK_HEADERS(dirent.h)
  47. AC_CHECK_HEADERS(fcntl.h)
  48. AC_CHECK_HEADERS(ifaddrs.h, [], [], [dnl
  49. #include <stdio.h>
  50. #ifdef STDC_HEADERS
  51. # include <stdlib.h>
  52. # include <stddef.h>
  53. #else
  54. # ifdef HAVE_STDLIB_H
  55. # include <stdlib.h>
  56. # endif
  57. #endif
  58. #ifdef HAVE_SYS_SOCKET_H
  59. # include <sys/socket.h>
  60. #endif
  61. ])
  62. AC_CHECK_HEADERS(malloc.h)
  63. AC_CHECK_HEADERS(netdb.h)
  64. AC_CHECK_HEADERS([netinet/in.h], [], [], [dnl
  65. #include <stdio.h>
  66. #ifdef STDC_HEADERS
  67. # include <stdlib.h>
  68. # include <stddef.h>
  69. #else
  70. # ifdef HAVE_STDLIB_H
  71. # include <stdlib.h>
  72. # endif
  73. #endif
  74. #ifdef HAVE_SYS_SOCKET_H
  75. # include <sys/socket.h>
  76. #endif
  77. ])
  78. AC_CHECK_HEADERS(netinet/tcp.h, [], [], [dnl
  79. #include <stdio.h>
  80. #ifdef STDC_HEADERS
  81. # include <stdlib.h>
  82. # include <stddef.h>
  83. #else
  84. # ifdef HAVE_STDLIB_H
  85. # include <stdlib.h>
  86. # endif
  87. #endif
  88. #ifdef HAVE_SYS_SOCKET_H
  89. # include <sys/socket.h>
  90. #endif
  91. ])
  92. AC_CHECK_HEADERS(pthread.h)
  93. AC_CHECK_HEADERS(strings.h)
  94. AC_CHECK_HEADERS(sys/ioctl.h)
  95. AC_CHECK_HEADERS(sys/param.h)
  96. AC_CHECK_HEADERS(sys/poll.h)
  97. AC_CHECK_HEADERS(sys/select.h)
  98. AC_CHECK_HEADERS(sys/stat.h)
  99. AC_CHECK_HEADERS(sys/time.h)
  100. AC_CHECK_HEADERS(sys/types.h)
  101. AC_CHECK_HEADERS(unistd.h)
  102. AC_CHECK_HEADERS([net/if.h], [], [], [dnl
  103. #include <stdio.h>
  104. #ifdef STDC_HEADERS
  105. # include <stdlib.h>
  106. # include <stddef.h>
  107. #else
  108. # ifdef HAVE_STDLIB_H
  109. # include <stdlib.h>
  110. # endif
  111. #endif
  112. #ifdef HAVE_SYS_SOCKET_H
  113. # include <sys/socket.h>
  114. #endif
  115. ])
  116. AC_HEADER_ASSERT
  117. AC_HEADER_STDBOOL
  118. AC_HEADER_TIME
  119. AC_C_BIGENDIAN
  120. AC_CHECK_FUNCS(strndup)
  121. AC_CHECK_FUNCS(strnlen)
  122. AC_CHECK_FUNCS(gettimeofday)
  123. AC_CHECK_FUNCS(usleep)
  124. AC_CHECK_FUNCS(vasprintf)
  125. build_bitbang=no
  126. build_bitq=no
  127. is_cygwin=no
  128. is_mingw=no
  129. is_win32=no
  130. is_darwin=no
  131. # guess-rev.sh only exists in the repository, not in the released archives
  132. AC_MSG_CHECKING([whether to build a release])
  133. if test -x $srcdir/guess-rev.sh ; then
  134. build_release=no
  135. else
  136. build_release=yes
  137. fi
  138. AC_MSG_RESULT($build_release)
  139. # We are not *ALWAYS* being installed in the standard place.
  140. # We may be installed in a "tool-build" specific location.
  141. # Normally with other packages - as part of a tool distro.
  142. # Thus - we should search that 'libdir' also.
  143. #
  144. # And - if we are being installed there - the odds are
  145. # The libraries unique to what we are are there too.
  146. #
  147. # Expand nd deal with NONE - just like configure will do later
  148. OCDprefix=$prefix
  149. OCDxprefix=$exec_prefix
  150. test x"$OCDprefix" = xNONE && OCDprefix=$ac_default_prefix
  151. # Let make expand exec_prefix.
  152. test x"$OCDxprefix" = xNONE && OCDxprefix="$OCDprefix"
  153. # what matters is the "exec-prefix"
  154. if test "$OCDxprefix" != "$ac_default_prefix"
  155. then
  156. # We are installing in a non-standard place
  157. # Nonstandard --prefix and/or --exec-prefix
  158. # We have an override of some sort.
  159. # use build specific install library dir
  160. LDFLAGS="$LDFLAGS -L$OCDxprefix/lib"
  161. # RPATH becomes an issue on Linux only
  162. if test $host_os = linux-gnu || test $host_os = linux ; then
  163. LDFLAGS="$LDFLAGS -Wl,-rpath,$OCDxprefix/lib"
  164. fi
  165. # The "INCDIR" is also usable
  166. CFLAGS="$CFLAGS -I$includedir"
  167. fi
  168. AC_ARG_WITH(ftd2xx,
  169. AS_HELP_STRING([--with-ftd2xx=<PATH>],[This option has been removed.]),
  170. [
  171. # Option Given.
  172. cat << __EOF__
  173. The option: --with-ftd2xx=<PATH> has been removed.
  174. On Linux, the new option is:
  175. --with-ftd2xx-linux-tardir=/path/to/files
  176. Where <path> is the path the the directory where the "tar.gz" file
  177. from FTDICHIP.COM was unpacked, for example:
  178. --with-ftd2xx-linux-tardir=${HOME}/libftd2xx0.4.16
  179. On Cygwin/MingW32, the new option is:
  180. --with-ftd2xx-win32-zipdir=/path/to/files
  181. Where <path> is the path to the directory where the "zip" file from
  182. FTDICHIP.COM was unpacked, for example:
  183. --with-ftd2xx-win32-zipdir=${HOME}/ftd2xx.cdm.files
  184. __EOF__
  185. AC_MSG_ERROR([Sorry Cannot continue])
  186. ], [true])
  187. #========================================
  188. # FTD2XXX support comes in 4 forms.
  189. # (1) win32 - via a zip file
  190. # (2) linux - via a tar file
  191. # (3) linux/cygwin/mingw - via libftdi
  192. # (4) darwin - installed under /usr/local
  193. #
  194. # In case (1) and (2) we need to know where the package was unpacked.
  195. AC_ARG_WITH(ftd2xx-win32-zipdir,
  196. AS_HELP_STRING([--with-ftd2xx-win32-zipdir],[Where (CYGWIN/MINGW) the zip file from ftdichip.com was unpacked <default=search>]),
  197. [
  198. # option present
  199. if test -d $with_ftd2xx_win32_zipdir
  200. then
  201. with_ftd2xx_win32_zipdir=`cd $with_ftd2xx_win32_zipdir && pwd`
  202. AC_MSG_NOTICE([Using: ftdichip.com library: $with_ftd2xx_win32_zipdir])
  203. else
  204. AC_MSG_ERROR([Parameter to --with-ftd2xx-win32-zipdir is not a dir: $with_ftd2xx_win32_zipdir])
  205. fi
  206. ], [true])
  207. AC_ARG_WITH(ftd2xx-linux-tardir,
  208. AS_HELP_STRING([--with-ftd2xx-linux-tardir], [Where (Linux/Unix) the tar file from ftdichip.com was unpacked <default=search>]),
  209. [
  210. # Option present
  211. if test $is_win32 = yes ; then
  212. AC_MSG_ERROR([The option: --with-ftd2xx-linux-tardir is only usable on linux])
  213. fi
  214. if test -d $with_ftd2xx_linux_tardir
  215. then
  216. with_ftd2xx_linux_tardir=`cd $with_ftd2xx_linux_tardir && pwd`
  217. AC_MSG_NOTICE([Using: ftdichip.com library: $with_ftd2xx_linux_tardir])
  218. else
  219. AC_MSG_ERROR([Parameter to --with-ftd2xx-linux-tardir is not a dir: $with_ftd2xx_linux_tardir])
  220. fi
  221. ], [true])
  222. AC_ARG_WITH(ftd2xx-lib,
  223. AS_HELP_STRING([--with-ftd2xx-lib],
  224. [Use static or shared ftd2xx libs on default static]),
  225. [
  226. case "$withval" in
  227. static)
  228. with_ftd2xx_lib=$withval
  229. ;;
  230. shared)
  231. with_ftd2xx_lib=$withval
  232. ;;
  233. *)
  234. AC_MSG_ERROR([Option: --with-ftd2xx-lib=static or --with-ftd2xx-lib=shared not, $withval])
  235. ;;
  236. esac
  237. ], [
  238. # Default is static - it is simpler :-(
  239. with_ftd2xx_lib=static
  240. ])
  241. AC_ARG_ENABLE(doxygen-html,
  242. AS_HELP_STRING([--disable-doxygen-html],
  243. [Disable building Doxygen manual as HTML.]),
  244. [doxygen_as_html=$enableval], [doxygen_as_html=yes])
  245. AC_SUBST(doxygen_as_html)
  246. AC_MSG_CHECKING([whether to build Doxygen as HTML])
  247. AC_MSG_RESULT($doxygen_as_html)
  248. AC_ARG_ENABLE(doxygen-pdf,
  249. AS_HELP_STRING([--enable-doxygen-pdf],
  250. [Enable building Doxygen manual as PDF.]),
  251. [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
  252. AC_SUBST(doxygen_as_pdf)
  253. AC_MSG_CHECKING([whether to build Doxygen as PDF])
  254. AC_MSG_RESULT($doxygen_as_pdf)
  255. AC_ARG_ENABLE(gccwarnings,
  256. AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
  257. [gcc_warnings=$enableval], [gcc_warnings=yes])
  258. AC_ARG_ENABLE(wextra,
  259. AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
  260. [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
  261. AC_ARG_ENABLE(werror,
  262. AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
  263. [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
  264. # set default verbose options, overridden by following options
  265. debug_jtag_io=no
  266. debug_usb_io=no
  267. debug_usb_comms=no
  268. AC_ARG_ENABLE(verbose,
  269. AS_HELP_STRING([--enable-verbose],
  270. [Enable verbose JTAG I/O messages (for debugging).]),
  271. [
  272. debug_jtag_io=$enableval
  273. debug_usb_io=$enableval
  274. debug_usb_comms=$enableval
  275. ], [])
  276. AC_ARG_ENABLE(verbose_jtag_io,
  277. AS_HELP_STRING([--enable-verbose-jtag-io],
  278. [Enable verbose JTAG I/O messages (for debugging).]),
  279. [debug_jtag_io=$enableval], [])
  280. AC_ARG_ENABLE(verbose_usb_io,
  281. AS_HELP_STRING([--enable-verbose-usb-io],
  282. [Enable verbose USB I/O messages (for debugging)]),
  283. [debug_usb_io=$enableval], [])
  284. AC_ARG_ENABLE(verbose_usb_comms,
  285. AS_HELP_STRING([--enable-verbose-usb-comms],
  286. [Enable verbose USB communication messages (for debugging)]),
  287. [debug_usb_comms=$enableval], [])
  288. AC_MSG_CHECKING([whether to enable verbose JTAG I/O messages]);
  289. AC_MSG_RESULT($debug_jtag_io)
  290. if test $debug_jtag_io = yes; then
  291. AC_DEFINE([_DEBUG_JTAG_IO_],[1], [Print verbose JTAG I/O messages])
  292. fi
  293. AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
  294. AC_MSG_RESULT($debug_usb_io)
  295. if test $debug_usb_io = yes; then
  296. AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
  297. fi
  298. AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
  299. AC_MSG_RESULT($debug_usb_comms)
  300. if test $debug_usb_comms = yes; then
  301. AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
  302. fi
  303. debug_malloc=no
  304. AC_ARG_ENABLE(malloc_logging,
  305. AS_HELP_STRING([--enable-malloc-logging],
  306. [Include free space in logging messages (requires malloc.h).]),
  307. [debug_malloc=$enableval], [])
  308. AC_MSG_CHECKING([whether to enable malloc free space logging]);
  309. AC_MSG_RESULT($debug_malloc)
  310. if test $debug_malloc = yes; then
  311. AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
  312. fi
  313. AC_ARG_ENABLE(dummy,
  314. AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
  315. [build_dummy=$enableval], [build_dummy=no])
  316. AC_ARG_ENABLE(parport,
  317. AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
  318. [build_parport=$enableval], [build_parport=no])
  319. AC_ARG_ENABLE(parport_ppdev,
  320. AS_HELP_STRING([--disable-parport-ppdev],
  321. [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
  322. [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
  323. AC_ARG_ENABLE(parport_giveio,
  324. AS_HELP_STRING([--enable-parport-giveio],
  325. [Enable use of giveio for parport (for CygWin only)]),
  326. [parport_use_giveio=$enableval], [parport_use_giveio=])
  327. AC_ARG_ENABLE(ft2232_libftdi,
  328. AS_HELP_STRING([--enable-ft2232_libftdi], [Enable building support for FT2232 based devices using the libftdi driver, opensource alternate of FTD2XX]),
  329. [build_ft2232_libftdi=$enableval], [build_ft2232_libftdi=no])
  330. AC_ARG_ENABLE(ft2232_ftd2xx,
  331. AS_HELP_STRING([--enable-ft2232_ftd2xx], [Enable building support for FT2232 based devices using the FTD2XX driver from ftdichip.com]),
  332. [build_ft2232_ftd2xx=$enableval], [build_ft2232_ftd2xx=no])
  333. AC_ARG_ENABLE(usb_blaster_libftdi,
  334. AS_HELP_STRING([--enable-usb_blaster_libftdi], [Enable building support for the Altera USB-Blaster using the libftdi driver, opensource alternate of FTD2XX]),
  335. [build_usb_blaster_libftdi=$enableval], [build_usb_blaster_libftdi=no])
  336. AC_ARG_ENABLE(usb_blaster_ftd2xx,
  337. AS_HELP_STRING([--enable-usb_blaster_ftd2xx], [Enable building support for the Altera USB-Blaster using the FTD2XX driver from ftdichip.com]),
  338. [build_usb_blaster_ftd2xx=$enableval], [build_usb_blaster_ftd2xx=no])
  339. AC_ARG_ENABLE(amtjtagaccel,
  340. AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
  341. [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
  342. AC_ARG_ENABLE(ecosboard,
  343. AS_HELP_STRING([--enable-ecosboard], [Enable building support for eCos based JTAG debugger]),
  344. [build_ecosboard=$enableval], [build_ecosboard=no])
  345. AC_ARG_ENABLE(zy1000_master,
  346. AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
  347. [build_zy1000_master=$enableval], [build_zy1000_master=no])
  348. AC_ARG_ENABLE(zy1000,
  349. AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
  350. [build_zy1000=$enableval], [build_zy1000=no])
  351. AC_ARG_ENABLE(ioutil,
  352. AS_HELP_STRING([--enable-ioutil], [Enable ioutil functions - useful for standalone OpenOCD implementations]),
  353. [build_ioutil=$enableval], [build_ioutil=no])
  354. case "${host_cpu}" in
  355. arm*)
  356. AC_ARG_ENABLE(ep93xx,
  357. AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
  358. [build_ep93xx=$enableval], [build_ep93xx=no])
  359. AC_ARG_ENABLE(at91rm9200,
  360. AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
  361. [build_at91rm9200=$enableval], [build_at91rm9200=no])
  362. ;;
  363. *)
  364. build_ep93xx=no
  365. build_at91rm9200=no
  366. ;;
  367. esac
  368. AC_ARG_ENABLE(gw16012,
  369. AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
  370. [build_gw16012=$enableval], [build_gw16012=no])
  371. AC_ARG_ENABLE(presto_libftdi,
  372. AS_HELP_STRING([--enable-presto_libftdi], [Enable building support for ASIX Presto Programmer using the libftdi driver]),
  373. [build_presto_libftdi=$enableval], [build_presto_libftdi=no])
  374. AC_ARG_ENABLE(presto_ftd2xx,
  375. AS_HELP_STRING([--enable-presto_ftd2xx], [Enable building support for ASIX Presto Programmer using the FTD2XX driver]),
  376. [build_presto_ftd2xx=$enableval], [build_presto_ftd2xx=no])
  377. AC_ARG_ENABLE(usbprog,
  378. AS_HELP_STRING([--enable-usbprog], [Enable building support for the usbprog JTAG Programmer]),
  379. [build_usbprog=$enableval], [build_usbprog=no])
  380. AC_ARG_ENABLE(oocd_trace,
  381. AS_HELP_STRING([--enable-oocd_trace],
  382. [Enable building support for some prototype OpenOCD+trace ETM capture hardware]),
  383. [build_oocd_trace=$enableval], [build_oocd_trace=no])
  384. AC_ARG_ENABLE(jlink,
  385. AS_HELP_STRING([--enable-jlink], [Enable building support for the Segger J-Link JTAG Programmer]),
  386. [build_jlink=$enableval], [build_jlink=no])
  387. AC_ARG_ENABLE(vsllink,
  388. AS_HELP_STRING([--enable-vsllink], [Enable building support for the Versaloon-Link JTAG Programmer]),
  389. [build_vsllink=$enableval], [build_vsllink=no])
  390. AC_ARG_ENABLE(rlink,
  391. AS_HELP_STRING([--enable-rlink], [Enable building support for the Raisonance RLink JTAG Programmer]),
  392. [build_rlink=$enableval], [build_rlink=no])
  393. AC_ARG_ENABLE(ulink,
  394. AS_HELP_STRING([--enable-ulink], [Enable building support for the Keil ULINK JTAG Programmer]),
  395. [build_ulink=$enableval], [build_ulink=no])
  396. AC_ARG_ENABLE(arm-jtag-ew,
  397. AS_HELP_STRING([--enable-arm-jtag-ew], [Enable building support for the Olimex ARM-JTAG-EW Programmer]),
  398. [build_armjtagew=$enableval], [build_armjtagew=no])
  399. AC_ARG_ENABLE(buspirate,
  400. AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
  401. [build_buspirate=$enableval], [build_buspirate=no])
  402. AC_ARG_ENABLE(minidriver_dummy,
  403. AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
  404. [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
  405. AC_ARG_ENABLE(internal-jimtcl,
  406. AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
  407. [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
  408. build_minidriver=no
  409. AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
  410. if test $build_zy1000 = yes; then
  411. if test $build_minidriver = yes; then
  412. AC_MSG_ERROR([Multiple minidriver options have been enabled.])
  413. fi
  414. AC_DEFINE(HAVE_JTAG_MINIDRIVER_H, 1,
  415. [Define to 1 if you have the <jtag_minidriver.h> header file.])
  416. build_minidriver=yes
  417. fi
  418. AC_MSG_RESULT($build_zy1000)
  419. AC_ARG_ENABLE(remote-bitbang,
  420. AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
  421. [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
  422. AC_MSG_CHECKING([whether to enable dummy minidriver])
  423. if test $build_minidriver_dummy = yes; then
  424. if test $build_minidriver = yes; then
  425. AC_MSG_ERROR([Multiple minidriver options have been enabled.])
  426. fi
  427. build_minidriver=yes
  428. AC_DEFINE(BUILD_MINIDRIVER_DUMMY, 1, [Use the dummy minidriver.])
  429. AC_DEFINE(HAVE_JTAG_MINIDRIVER_H, 1,
  430. [Define to 1 if you have the <jtag_minidriver.h> header file.])
  431. fi
  432. AC_MSG_RESULT($build_minidriver_dummy)
  433. AC_MSG_CHECKING([whether standard drivers can be built])
  434. if test "$build_minidriver" = yes; then
  435. AC_MSG_RESULT([no])
  436. AC_MSG_WARN([Using the minidriver disables all other drivers.])
  437. sleep 2
  438. else
  439. AC_MSG_RESULT([yes])
  440. fi
  441. case "${host_cpu}" in
  442. i?86|x86*)
  443. ;;
  444. *)
  445. if test x$parport_use_ppdev = xno; then
  446. AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
  447. fi
  448. parport_use_ppdev=yes
  449. ;;
  450. esac
  451. case $host in
  452. *-cygwin*)
  453. is_win32=yes
  454. parport_use_ppdev=no
  455. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
  456. [is_mingw=yes],[is_mingw=no])
  457. if test $is_mingw = yes; then
  458. AC_DEFINE(IS_MINGW, 1, [1 if building for MinGW.])
  459. if test x$parport_use_giveio = xno; then
  460. AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
  461. fi
  462. parport_use_giveio=yes
  463. is_cygwin=no
  464. else
  465. is_cygwin=yes
  466. AC_DEFINE(IS_CYGWIN, 1, [1 if building for Cygwin.])
  467. # sys/io.h needed under cygwin for parport access
  468. if test $build_parport = yes; then
  469. AC_CHECK_HEADERS(sys/io.h,[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
  470. fi
  471. fi
  472. AC_DEFINE(IS_WIN32, 1, [1 if building for Win32.])
  473. AC_DEFINE(IS_DARWIN, 0, [0 if not building for Darwin.])
  474. ;;
  475. *-mingw*)
  476. is_mingw=yes
  477. is_win32=yes
  478. parport_use_ppdev=no
  479. if test x$parport_use_giveio = xno; then
  480. AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
  481. fi
  482. parport_use_giveio=yes
  483. if test x$build_buspirate = xyes; then
  484. AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
  485. fi
  486. CFLAGS="$CFLAGS -D__USE_MINGW_ANSI_STDIO"
  487. AC_DEFINE(IS_MINGW, 1, [1 if building for MinGW.])
  488. AC_DEFINE(IS_WIN32, 1, [1 if building for Win32.])
  489. AC_DEFINE(IS_DARWIN, 0, [0 if not building for Darwin.])
  490. ;;
  491. *darwin*)
  492. is_darwin=yes
  493. if test x$parport_use_giveio = xyes; then
  494. AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
  495. fi
  496. parport_use_giveio=no
  497. AC_DEFINE(IS_CYGWIN, 0, [0 if not building for Cygwin.])
  498. AC_DEFINE(IS_WIN32, 0, [0 if not building for Win32.])
  499. AC_DEFINE(IS_DARWIN, 1, [1 if building for Darwin.])
  500. ;;
  501. *)
  502. if test x$parport_use_giveio = xyes; then
  503. AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
  504. fi
  505. parport_use_giveio=no
  506. AC_DEFINE(IS_CYGWIN, 0, [0 if not building for Cygwin.])
  507. AC_DEFINE(IS_WIN32, 0, [0 if not building for Win32.])
  508. AC_DEFINE(IS_DARWIN, 0, [0 if not building for Darwin.])
  509. ;;
  510. esac
  511. if test $build_parport = yes; then
  512. build_bitbang=yes
  513. AC_DEFINE(BUILD_PARPORT, 1, [1 if you want parport.])
  514. else
  515. AC_DEFINE(BUILD_PARPORT, 0, [0 if you don't want parport.])
  516. fi
  517. if test $build_dummy = yes; then
  518. build_bitbang=yes
  519. AC_DEFINE(BUILD_DUMMY, 1, [1 if you want dummy driver.])
  520. else
  521. AC_DEFINE(BUILD_DUMMY, 0, [0 if you don't want dummy driver.])
  522. fi
  523. if test $build_ep93xx = yes; then
  524. build_bitbang=yes
  525. AC_DEFINE(BUILD_EP93XX, 1, [1 if you want ep93xx.])
  526. else
  527. AC_DEFINE(BUILD_EP93XX, 0, [0 if you don't want ep93xx.])
  528. fi
  529. if test $build_ecosboard = yes; then
  530. AC_DEFINE(BUILD_ECOSBOARD, 1, [1 if you want eCosBoard.])
  531. else
  532. AC_DEFINE(BUILD_ECOSBOARD, 0, [0 if you don't want eCosBoard.])
  533. fi
  534. if test $build_zy1000 = yes; then
  535. AC_DEFINE(BUILD_ZY1000, 1, [1 if you want ZY1000.])
  536. else
  537. AC_DEFINE(BUILD_ZY1000, 0, [0 if you don't want ZY1000.])
  538. fi
  539. if test $build_zy1000_master = yes; then
  540. AC_DEFINE(BUILD_ZY1000_MASTER, 1, [1 if you want ZY1000 JTAG master registers.])
  541. else
  542. AC_DEFINE(BUILD_ZY1000_MASTER, 0, [0 if you don't want ZY1000 JTAG master registers.])
  543. fi
  544. if test $build_at91rm9200 = yes; then
  545. build_bitbang=yes
  546. AC_DEFINE(BUILD_AT91RM9200, 1, [1 if you want at91rm9200.])
  547. else
  548. AC_DEFINE(BUILD_AT91RM9200, 0, [0 if you don't want at91rm9200.])
  549. fi
  550. if test x$parport_use_ppdev = xyes; then
  551. AC_DEFINE(PARPORT_USE_PPDEV, 1, [1 if you want parport to use ppdev.])
  552. else
  553. AC_DEFINE(PARPORT_USE_PPDEV, 0, [0 if you don't want parport to use ppdev.])
  554. fi
  555. if test x$parport_use_giveio = xyes; then
  556. AC_DEFINE(PARPORT_USE_GIVEIO, 1, [1 if you want parport to use giveio.])
  557. else
  558. AC_DEFINE(PARPORT_USE_GIVEIO, 0, [0 if you don't want parport to use giveio.])
  559. fi
  560. if test $build_bitbang = yes; then
  561. AC_DEFINE(BUILD_BITBANG, 1, [1 if you want a bitbang interface.])
  562. else
  563. AC_DEFINE(BUILD_BITBANG, 0, [0 if you don't want a bitbang interface.])
  564. fi
  565. if test $build_ft2232_libftdi = yes; then
  566. AC_DEFINE(BUILD_FT2232_LIBFTDI, 1, [1 if you want libftdi ft2232.])
  567. else
  568. AC_DEFINE(BUILD_FT2232_LIBFTDI, 0, [0 if you don't want libftdi ft2232.])
  569. fi
  570. if test $build_ft2232_ftd2xx = yes; then
  571. AC_DEFINE(BUILD_FT2232_FTD2XX, 1, [1 if you want ftd2xx ft2232.])
  572. else
  573. AC_DEFINE(BUILD_FT2232_FTD2XX, 0, [0 if you don't want ftd2xx ft2232.])
  574. fi
  575. if test $build_usb_blaster_libftdi = yes; then
  576. build_bitbang=yes
  577. AC_DEFINE(BUILD_USB_BLASTER_LIBFTDI, 1, [1 if you want libftdi usb_blaster.])
  578. else
  579. AC_DEFINE(BUILD_USB_BLASTER_LIBFTDI, 0, [0 if you don't want libftdi usb_blaster.])
  580. fi
  581. if test $build_usb_blaster_ftd2xx = yes; then
  582. build_bitbang=yes
  583. AC_DEFINE(BUILD_USB_BLASTER_FTD2XX, 1, [1 if you want ftd2xx usb_blaster.])
  584. else
  585. AC_DEFINE(BUILD_USB_BLASTER_FTD2XX, 0, [0 if you don't want ftd2xx usb_blaster.])
  586. fi
  587. if test $build_amtjtagaccel = yes; then
  588. AC_DEFINE(BUILD_AMTJTAGACCEL, 1, [1 if you want the Amontec JTAG-Accelerator driver.])
  589. else
  590. AC_DEFINE(BUILD_AMTJTAGACCEL, 0, [0 if you don't want the Amontec JTAG-Accelerator driver.])
  591. fi
  592. if test $build_gw16012 = yes; then
  593. AC_DEFINE(BUILD_GW16012, 1, [1 if you want the Gateworks GW16012 driver.])
  594. else
  595. AC_DEFINE(BUILD_GW16012, 0, [0 if you don't want the Gateworks GW16012 driver.])
  596. fi
  597. if test $build_presto_libftdi = yes; then
  598. build_bitq=yes
  599. AC_DEFINE(BUILD_PRESTO_LIBFTDI, 1, [1 if you want the ASIX PRESTO driver using libftdi.])
  600. else
  601. AC_DEFINE(BUILD_PRESTO_LIBFTDI, 0, [0 if you don't want the ASIX PRESTO driver using libftdi.])
  602. fi
  603. if test $build_presto_ftd2xx = yes; then
  604. build_bitq=yes
  605. AC_DEFINE(BUILD_PRESTO_FTD2XX, 1, [1 if you want the ASIX PRESTO driver using FTD2XX.])
  606. else
  607. AC_DEFINE(BUILD_PRESTO_FTD2XX, 0, [0 if you don't want the ASIX PRESTO driver using FTD2XX.])
  608. fi
  609. if test $build_bitq = yes; then
  610. AC_DEFINE(BUILD_BITQ, 1, [1 if you want a bitq interface.])
  611. else
  612. AC_DEFINE(BUILD_BITQ, 0, [0 if you don't want a bitq interface.])
  613. fi
  614. if test $build_usbprog = yes; then
  615. AC_DEFINE(BUILD_USBPROG, 1, [1 if you want the usbprog JTAG driver.])
  616. else
  617. AC_DEFINE(BUILD_USBPROG, 0, [0 if you don't want the usbprog JTAG driver.])
  618. fi
  619. if test $build_oocd_trace = yes; then
  620. AC_DEFINE(BUILD_OOCD_TRACE, 1, [1 if you want the OpenOCD+trace ETM capture driver.])
  621. else
  622. AC_DEFINE(BUILD_OOCD_TRACE, 0, [0 if you don't want the OpenOCD+trace ETM capture driver.])
  623. fi
  624. if test $build_jlink = yes; then
  625. AC_DEFINE(BUILD_JLINK, 1, [1 if you want the J-Link JTAG driver.])
  626. else
  627. AC_DEFINE(BUILD_JLINK, 0, [0 if you don't want the J-Link JTAG driver.])
  628. fi
  629. if test $build_vsllink = yes; then
  630. AC_DEFINE(BUILD_VSLLINK, 1, [1 if you want the Versaloon-Link JTAG driver.])
  631. else
  632. AC_DEFINE(BUILD_VSLLINK, 0, [0 if you don't want the Versaloon-Link JTAG driver.])
  633. fi
  634. if test $build_rlink = yes; then
  635. AC_DEFINE(BUILD_RLINK, 1, [1 if you want the RLink JTAG driver.])
  636. else
  637. AC_DEFINE(BUILD_RLINK, 0, [0 if you don't want the RLink JTAG driver.])
  638. fi
  639. if test $build_ulink = yes; then
  640. AC_DEFINE(BUILD_ULINK, 1, [1 if you want the ULINK JTAG driver.])
  641. else
  642. AC_DEFINE(BUILD_ULINK, 0, [0 if you don't want the ULINK JTAG driver.])
  643. fi
  644. if test $build_armjtagew = yes; then
  645. AC_DEFINE(BUILD_ARMJTAGEW, 1, [1 if you want the ARM-JTAG-EW JTAG driver.])
  646. else
  647. AC_DEFINE(BUILD_ARMJTAGEW, 0, [0 if you don't want the ARM-JTAG-EW JTAG driver.])
  648. fi
  649. if test $build_buspirate = yes; then
  650. AC_DEFINE(BUILD_BUSPIRATE, 1, [1 if you want the Buspirate JTAG driver.])
  651. else
  652. AC_DEFINE(BUILD_BUSPIRATE, 0, [0 if you don't want the Buspirate JTAG driver.])
  653. fi
  654. if test "$use_internal_jimtcl" = yes; then
  655. if test -f "$srcdir/jimtcl/configure.ac"; then
  656. AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
  657. else
  658. AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
  659. fi
  660. fi
  661. if test $build_remote_bitbang = yes; then
  662. build_bitbang=yes
  663. AC_DEFINE(BUILD_REMOTE_BITBANG, 1, [1 if you want the Remote Bitbang JTAG driver.])
  664. else
  665. AC_DEFINE(BUILD_REMOTE_BITBNAG, 0, [0 if you don't want the Remote Bitbang JTAG driver.])
  666. fi
  667. #-- Deal with MingW/Cygwin FTD2XX issues
  668. if test $is_win32 = yes; then
  669. if test "${with_ftd2xx_linux_tardir+set}" = set
  670. then
  671. AC_MSG_ERROR([The option: with_ftd2xx_linux_tardir is for LINUX only.])
  672. fi
  673. if test $build_ft2232_ftd2xx = yes -o $build_presto_ftd2xx = yes -o $build_usb_blaster_ftd2xx = yes ; then
  674. AC_MSG_CHECKING([for ftd2xx.lib exists (win32)])
  675. # if we are given a zipdir...
  676. if test "${with_ftd2xx_win32_zipdir+set}" = set
  677. then
  678. # Set the CFLAGS for "ftd2xx.h"
  679. f=$with_ftd2xx_win32_zipdir/ftd2xx.h
  680. if test ! -f $f ; then
  681. AC_MSG_ERROR([File: $f cannot be found])
  682. fi
  683. CFLAGS="$CFLAGS -I$with_ftd2xx_win32_zipdir"
  684. # And calculate the LDFLAGS for the machine
  685. case "$host_cpu" in
  686. i?86|x86_32)
  687. LDFLAGS="$LDFLAGS -L$with_ftd2xx_win32_zipdir/i386"
  688. LIBS="$LIBS -lftd2xx"
  689. f=$with_ftd2xx_win32_zipdir/i386/ftd2xx.lib
  690. ;;
  691. amd64|x86_64)
  692. LDFLAGS="$LDFLAGS -L$with_ftd2xx_win32_zipdir/amd64"
  693. LIBS="$LIBS -lftd2xx"
  694. f=$with_ftd2xx_win32_zipdir/amd64/ftd2xx.lib
  695. ;;
  696. *)
  697. AC_MSG_ERROR([Unknown Win32 host cpu: $host_cpu])
  698. ;;
  699. esac
  700. if test ! -f $f ; then
  701. AC_MSG_ERROR([Library: $f not found])
  702. fi
  703. else
  704. LIBS="$LIBS -lftd2xx"
  705. AC_MSG_WARN([ASSUMPTION: The (win32) FTDICHIP.COM files: ftd2xx.h and ftd2xx.lib are in a proper place])
  706. fi
  707. fi
  708. fi # win32
  709. if test $is_darwin = yes ; then
  710. if test "${with_ftd2xx_win32_zipdir+set}" = set
  711. then
  712. AC_MSG_ERROR([The option: --with-ftd2xx-win32-zipdir is for win32 only])
  713. fi
  714. if test "${with_ftd2xx_linux_tardir+set}" = set
  715. then
  716. AC_MSG_ERROR([The option: with_ftd2xx_linux_tardir is for LINUX only.])
  717. fi
  718. if test $build_ft2232_ftd2xx = yes -o $build_presto_ftd2xx = yes ; then
  719. AC_MSG_CHECKING([for libftd2xx.a (darwin)])
  720. if test ! -f /usr/local/include/ftd2xx.h ; then
  721. AC_MSG_ERROR([ftd2xx library from FTDICHIP.com seems to be missing, cannot find: /usr/local/include/ftd2xx.h])
  722. fi
  723. CFLAGS="$CFLAGS -I/usr/local/include"
  724. LDFLAGS="$LDFLAGS -L/usr/local/lib"
  725. LIBS="$LIBS -lftd2xx"
  726. AC_MSG_RESULT([-L/usr/local/lib -lftd2xx])
  727. fi
  728. fi # darwin
  729. if test $is_win32 = no && test $is_darwin = no ; then
  730. if test "${with_ftd2xx_win32_zipdir+set}" = set
  731. then
  732. AC_MSG_ERROR([The option: --with-ftd2xx-win32-zipdir is for win32 only])
  733. fi
  734. if test $build_ft2232_ftd2xx = yes -o $build_presto_ftd2xx = yes ; then
  735. # Must be linux
  736. if test $host_os != linux-gnu && test $host_os != linux ; then
  737. AC_MSG_ERROR([The (linux) ftd2xx library from FTDICHIP.com is linux only. Try --enable-ft2232-libftdi instead])
  738. fi
  739. # Are we given a TAR directory?
  740. if test "${with_ftd2xx_linux_tardir+set}" = set
  741. then
  742. AC_MSG_CHECKING([uninstalled ftd2xx distribution])
  743. # The .H file is simple..
  744. FTD2XX_H=$with_ftd2xx_linux_tardir/ftd2xx.h
  745. if test ! -f "${FTD2XX_H}"; then
  746. AC_MSG_ERROR([Option: --with-ftd2xx-linux-tardir appears wrong, cannot find: ${FTD2XX_H}])
  747. fi
  748. CFLAGS="$CFLAGS -I$with_ftd2xx_linux_tardir"
  749. if test $with_ftd2xx_lib = shared; then
  750. FTD2XX_LDFLAGS="-L$with_ftd2xx_linux_tardir"
  751. FTD2XX_LIB="-lftd2xx"
  752. else
  753. # Test #1 - v1.0.x
  754. case "$host_cpu" in
  755. i?86|x86_32)
  756. dir=build/i386;;
  757. amd64|x86_64)
  758. dir=build/x86_64;;
  759. *)
  760. dir=none;;
  761. esac
  762. if test -f "$with_ftd2xx_linux_tardir/$dir/libftd2xx.a"; then
  763. FTD2XX_LDFLAGS="-L$with_ftd2xx_linux_tardir/$dir"
  764. # Also needs -lrt
  765. FTD2XX_LIB="-lftd2xx -lrt"
  766. else
  767. # Test Number2.
  768. # Grr.. perhaps it exists as a version number?
  769. FTD2XX_LIB="$with_ftd2xx_linux_tardir/static_lib/libftd2xx.a.*.*.*"
  770. count=`ls ${FTD2XX_LIB} | wc -l`
  771. if test $count -gt 1 ; then
  772. AC_MSG_ERROR([Multiple libftd2xx.a files found in: $with_ftd2xx_linux_tardir/static_lib sorry cannot handle this yet])
  773. fi
  774. if test $count -ne 1 ; then
  775. AC_MSG_ERROR([Not found: $f, option: --with-ftd2xx-linux-tardir appears to be wrong])
  776. fi
  777. # Because the "-l" rules do not understand version numbers...
  778. # we will just stuff the absolute path onto the LIBS variable
  779. FTD2XX_LIB="`ls ${FTD2XX_LIB}` -lpthread"
  780. FTD2XX_LDFLAGS=""
  781. fi
  782. fi
  783. LDFLAGS="${LDFLAGS} ${FTD2XX_LDFLAGS}"
  784. LIBS="${LIBS} ${FTD2XX_LIB}"
  785. AC_MSG_RESULT([${FTD2XX_LDFLAGS} ${FTD2XX_LIB}])
  786. else
  787. AC_CHECK_HEADER([ftd2xx.h],[],[
  788. AC_MSG_ERROR([You seem to be missing the FTD2xx driver header file.])
  789. ])
  790. AC_SEARCH_LIBS([FT_GetLibraryVersion],[ftd2xx],,[
  791. AC_MSG_ERROR([You appear to be missing the FTD2xx driver library.])
  792. ],[])
  793. fi
  794. fi
  795. fi # linux
  796. if test $build_ft2232_ftd2xx = yes -o $build_presto_ftd2xx = yes; then
  797. # Before we go any further - make sure we can *BUILD* and *RUN*
  798. # a simple app with the "ftd2xx.lib" file - in what ever form we where given
  799. # We should be able to compile, link and run this test program now
  800. AC_MSG_CHECKING([whether ftd2xx library works])
  801. #
  802. # Save the LDFLAGS for later..
  803. LDFLAGS_SAVE=$LDFLAGS
  804. CFLAGS_SAVE=$CFLAGS
  805. _LDFLAGS=`eval echo $LDFLAGS`
  806. _CFLAGS=`eval echo $CFLAGS`
  807. LDFLAGS=$_LDFLAGS
  808. CFLAGS=$_CFLAGS
  809. AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  810. #include "confdefs.h"
  811. #if IS_WIN32
  812. #include "windows.h"
  813. #endif
  814. #include <stdio.h>
  815. #include <ftd2xx.h>
  816. ]], [[
  817. DWORD x;
  818. FT_GetLibraryVersion( &x );
  819. ]])], [
  820. AC_MSG_RESULT([Success!])
  821. ], [
  822. AC_MSG_ERROR([Cannot build & run test program using ftd2xx.lib])
  823. ], [
  824. AC_MSG_RESULT([Skipping as we are cross-compiling])
  825. ])
  826. AC_MSG_CHECKING([for ftd2xx highspeed device support])
  827. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  828. #include "confdefs.h"
  829. #if IS_WIN32
  830. #include "windows.h"
  831. #endif
  832. #include <stdio.h>
  833. #include <ftd2xx.h>
  834. DWORD x = FT_DEVICE_4232H;
  835. ]], [])], [
  836. AC_DEFINE(BUILD_FT2232_HIGHSPEED, [1],
  837. [Support FT2232H/FT4232HS with FTD2XX or libftdi.])
  838. build_ft2232_highspeed=yes
  839. ], [
  840. build_ft2232_highspeed=no
  841. ])
  842. AC_MSG_RESULT([$build_ft2232_highspeed])
  843. if test $build_ft2232_highspeed = no; then
  844. AC_MSG_WARN([You need a newer FTD2XX driver (version 2.04.16 or later).])
  845. fi
  846. LDFLAGS=$LDFLAGS_SAVE
  847. CFLAGS=$CFLAGS_SAVE
  848. fi
  849. if test $build_ft2232_libftdi = yes ; then
  850. # We assume: the package is preinstalled in the proper place
  851. # these present as 2 libraries..
  852. LIBS="$LIBS -lftdi -lusb"
  853. #
  854. # Try to build a small program.
  855. AC_MSG_CHECKING([Build & Link with libftdi...])
  856. LDFLAGS_SAVE=$LDFLAGS
  857. CFLAGS_SAVE=$CFLAGS
  858. _LDFLAGS=`eval echo $LDFLAGS`
  859. _CFLAGS=`eval echo $CFLAGS`
  860. LDFLAGS=$_LDFLAGS
  861. CFLAGS=$_CFLAGS
  862. AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  863. #include <stdio.h>
  864. #include <ftdi.h>
  865. ]], [[
  866. struct ftdi_context *p;
  867. p = ftdi_new();
  868. if( p != NULL ){
  869. return 0;
  870. } else {
  871. fprintf( stderr, "calling ftdi_new() failed\n");
  872. return 1;
  873. }
  874. ]])], [
  875. AC_MSG_RESULT([Success])
  876. ], [
  877. AC_MSG_ERROR([Cannot build & run test program using libftdi])
  878. ], [
  879. AC_MSG_RESULT([Skipping as we are cross-compiling])
  880. ])
  881. AC_MSG_CHECKING([for libftdi highspeed device support])
  882. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  883. #include <stdio.h>
  884. #include <ftdi.h>
  885. ]], [[
  886. enum ftdi_chip_type x = TYPE_2232H;
  887. ]])], [
  888. AC_DEFINE(BUILD_FT2232_HIGHSPEED, [1],
  889. [Support FT2232H/FT4232HS with FTD2XX or libftdi.])
  890. build_ft2232_highspeed=yes
  891. ], [
  892. build_ft2232_highspeed=no
  893. ])
  894. AC_MSG_RESULT([$build_ft2232_highspeed])
  895. if test $build_ft2232_highspeed = no; then
  896. AC_MSG_WARN([You need a newer libftdi version (0.16 or later).])
  897. fi
  898. # Restore the 'unexpanded ldflags'
  899. LDFLAGS=$LDFLAGS_SAVE
  900. CFLAGS=$CFLAGS_SAVE
  901. fi
  902. # check for usb.h when a driver will require it
  903. build_usb=no
  904. if test $build_jlink = yes -o $build_vsllink = yes -o $build_usbprog = yes -o \
  905. $build_rlink = yes -o $build_ulink = yes -o $build_armjtagew = yes
  906. then
  907. AC_CHECK_HEADERS([usb.h],[],
  908. [AC_MSG_ERROR([usb.h is required to build some OpenOCD driver(s)])])
  909. build_usb=yes
  910. fi
  911. AM_CONDITIONAL(RELEASE, test $build_release = yes)
  912. AM_CONDITIONAL(PARPORT, test $build_parport = yes)
  913. AM_CONDITIONAL(DUMMY, test $build_dummy = yes)
  914. AM_CONDITIONAL(GIVEIO, test x$parport_use_giveio = xyes)
  915. AM_CONDITIONAL(EP93XX, test $build_ep93xx = yes)
  916. AM_CONDITIONAL(ECOSBOARD, test $build_ecosboard = yes)
  917. AM_CONDITIONAL(ZY1000, test $build_zy1000 = yes)
  918. AM_CONDITIONAL(ZY1000_MASTER, test $build_zy1000_master = yes)
  919. AM_CONDITIONAL(IOUTIL, test $build_ioutil = yes)
  920. AM_CONDITIONAL(AT91RM9200, test $build_at91rm9200 = yes)
  921. AM_CONDITIONAL(BITBANG, test $build_bitbang = yes)
  922. AM_CONDITIONAL(FT2232_LIBFTDI, test $build_ft2232_libftdi = yes)
  923. AM_CONDITIONAL(FT2232_DRIVER, test $build_ft2232_ftd2xx = yes -o $build_ft2232_libftdi = yes)
  924. AM_CONDITIONAL(USB_BLASTER_LIBFTDI, test $build_usb_blaster_libftdi = yes)
  925. AM_CONDITIONAL(USB_BLASTER_DRIVER, test $build_usb_blaster_ftd2xx = yes -o $build_usb_blaster_libftdi = yes)
  926. AM_CONDITIONAL(AMTJTAGACCEL, test $build_amtjtagaccel = yes)
  927. AM_CONDITIONAL(GW16012, test $build_gw16012 = yes)
  928. AM_CONDITIONAL(PRESTO_LIBFTDI, test $build_presto_libftdi = yes)
  929. AM_CONDITIONAL(PRESTO_DRIVER, test $build_presto_ftd2xx = yes -o $build_presto_libftdi = yes)
  930. AM_CONDITIONAL(USBPROG, test $build_usbprog = yes)
  931. AM_CONDITIONAL(OOCD_TRACE, test $build_oocd_trace = yes)
  932. AM_CONDITIONAL(JLINK, test $build_jlink = yes)
  933. AM_CONDITIONAL(VSLLINK, test $build_vsllink = yes)
  934. AM_CONDITIONAL(RLINK, test $build_rlink = yes)
  935. AM_CONDITIONAL(ULINK, test $build_ulink = yes)
  936. AM_CONDITIONAL(ARMJTAGEW, test $build_armjtagew = yes)
  937. AM_CONDITIONAL(REMOTE_BITBANG, test $build_remote_bitbang = yes)
  938. AM_CONDITIONAL(BUSPIRATE, test $build_buspirate = yes)
  939. AM_CONDITIONAL(USB, test $build_usb = yes)
  940. AM_CONDITIONAL(IS_CYGWIN, test $is_cygwin = yes)
  941. AM_CONDITIONAL(IS_MINGW, test $is_mingw = yes)
  942. AM_CONDITIONAL(IS_WIN32, test $is_win32 = yes)
  943. AM_CONDITIONAL(IS_DARWIN, test $is_darwin = yes)
  944. AM_CONDITIONAL(BITQ, test $build_bitq = yes)
  945. AM_CONDITIONAL(MINIDRIVER, test $build_minidriver = yes)
  946. AM_CONDITIONAL(MINIDRIVER_DUMMY, test $build_minidriver_dummy = yes)
  947. AM_CONDITIONAL(INTERNAL_JIMTCL, test $use_internal_jimtcl = yes)
  948. # Look for environ alternatives. Possibility #1: is environ in unistd.h or stdlib.h?
  949. AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
  950. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  951. #define _GNU_SOURCE
  952. #include <unistd.h>
  953. #include <stdlib.h>
  954. ]], [[char **ep = environ;]]
  955. )], [
  956. AC_MSG_RESULT([yes])
  957. has_environ=yes
  958. ], [
  959. AC_MSG_RESULT([no])
  960. # Possibility #2: can environ be found in an available library?
  961. AC_MSG_CHECKING([for extern environ])
  962. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  963. extern char **environ;
  964. ]], [[char **ep = environ;]]
  965. )], [
  966. AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
  967. has_environ=yes
  968. ], [
  969. has_environ=no
  970. ])
  971. AC_MSG_RESULT([${has_environ}])
  972. ])
  973. if test "${has_environ}" != "yes" ; then
  974. AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
  975. fi
  976. AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
  977. # set default gcc warnings
  978. GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
  979. if test "${gcc_wextra}" = yes; then
  980. GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
  981. GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
  982. GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
  983. GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
  984. fi
  985. if test "${gcc_werror}" = yes; then
  986. GCC_WARNINGS="${GCC_WARNINGS} -Werror"
  987. fi
  988. # overide default gcc cflags
  989. if test $gcc_warnings = yes; then
  990. CFLAGS="$CFLAGS $GCC_WARNINGS"
  991. fi
  992. # Setup for compiling build tools
  993. AC_MSG_CHECKING([for a C compiler for build tools])
  994. if test $cross_compiling = yes; then
  995. AC_CHECK_PROGS(CC_FOR_BUILD, gcc cc)
  996. CFLAGS_FOR_BUILD="-g -O2 $GCC_WARNINGS"
  997. else
  998. CC_FOR_BUILD=$CC
  999. CFLAGS_FOR_BUILD=$CFLAGS
  1000. fi
  1001. AC_MSG_RESULT([$CC_FOR_BUILD])
  1002. AC_SUBST(CC_FOR_BUILD)
  1003. AC_SUBST(CFLAGS_FOR_BUILD)
  1004. AC_MSG_CHECKING([for suffix of executable build tools])
  1005. if test $cross_compiling = yes; then
  1006. cat >conftest.c <<\_______EOF
  1007. int main ()
  1008. {
  1009. exit (0);
  1010. }
  1011. _______EOF
  1012. for i in .exe ""; do
  1013. compile="$CC_FOR_BUILD conftest.c -o conftest$i"
  1014. if AC_TRY_EVAL(compile); then
  1015. if (./conftest) 2>&AC_FD_CC; then
  1016. EXEEXT_FOR_BUILD=$i
  1017. break
  1018. fi
  1019. fi
  1020. done
  1021. rm -f conftest*
  1022. if test "${EXEEXT_FOR_BUILD+set}" != set; then
  1023. AC_MSG_ERROR([Cannot determine suffix of executable build tools])
  1024. fi
  1025. else
  1026. EXEEXT_FOR_BUILD=$EXEEXT
  1027. fi
  1028. AC_MSG_RESULT([$EXEEXT_FOR_BUILD])
  1029. AC_SUBST(EXEEXT_FOR_BUILD)
  1030. AC_OUTPUT(dnl
  1031. Makefile dnl
  1032. src/Makefile dnl
  1033. src/helper/Makefile dnl
  1034. src/jtag/Makefile dnl
  1035. src/jtag/drivers/Makefile dnl
  1036. src/transport/Makefile dnl
  1037. src/xsvf/Makefile dnl
  1038. src/svf/Makefile dnl
  1039. src/target/Makefile dnl
  1040. src/rtos/Makefile dnl
  1041. src/server/Makefile dnl
  1042. src/flash/Makefile dnl
  1043. src/flash/nor/Makefile dnl
  1044. src/flash/nand/Makefile dnl
  1045. src/pld/Makefile dnl
  1046. doc/Makefile dnl
  1047. )