openocd/configure.in

AC_INIT(configure.in)

AC_SEARCH_LIBS([ioperm], [ioperm])

AC_CANONICAL_HOST

AC_C_BIGENDIAN

AC_CHECK_FUNCS(strndup)
AC_CHECK_FUNCS(strnlen)
AC_CHECK_FUNCS(gettimeofday)
AC_CHECK_FUNCS(usleep)

build_bitbang=no
is_cygwin=no
is_mingw=no
is_win32=no

AC_ARG_ENABLE(parport,
  AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]), 
  [build_parport=$enableval], [build_parport=no])

AC_ARG_ENABLE(parport_ppdev,
  AS_HELP_STRING([--enable-parport_ppdev], [Enable use of ppdev (/dev/parportN) for parport]), 
  [parport_use_ppdev=$enableval], [parport_use_ppdev=no])

AC_ARG_ENABLE(ft2232_libftdi,
  AS_HELP_STRING([--enable-ft2232_libftdi], [Enable building support for FT2232 based devices using the libftdi driver]), 
  [build_ft2232_libftdi=$enableval], [build_ft2232_libftdi=no])

AC_ARG_ENABLE(ft2232_ftd2xx,
  AS_HELP_STRING([--enable-ft2232_ftd2xx], [Enable building support for FT2232 based devices using the FTD2XX driver]), 
  [build_ft2232_ftd2xx=$enableval], [build_ft2232_ftd2xx=no])
 
AC_ARG_ENABLE(amtjtagaccel,
  AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]), 
  [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])

AC_ARG_ENABLE(ep93xx,
  AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]), 
  [build_ep93xx=$enableval], [build_ep93xx=no])

AC_ARG_ENABLE(at91rm9200,
  AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
  [build_at91rm9200=$enableval], [build_at91rm9200=no])

AC_ARG_ENABLE(gw16012,
  AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
  [build_gw16012=$enableval], [build_gw16012=no])

AC_ARG_WITH(ftd2xx,
        [AS_HELP_STRING(--with-ftd2xx,
           [Where libftd2xx can be found <default=search>])],
        [],
        with_ftd2xx=search)

case $host in 
  *-*-cygwin*) 
    is_win32=yes

    AC_ARG_ENABLE(parport_giveio,
    AS_HELP_STRING([--enable-parport_giveio], [Enable use of giveio for parport instead of ioperm]), 
    [parport_use_giveio=$enableval], [parport_use_giveio=no])
	
	AC_COMPILE_IFELSE(AC_LANG_PROGRAM([],[return __MINGW32__;]),[is_mingw=yes],[is_mingw=no])
	if test $is_mingw = yes; then
		AC_DEFINE(IS_MINGW, 1, [1 if building for MinGW.])
		parport_use_giveio=yes
		is_cygwin=no
	else
		is_cygwin=yes
		AC_DEFINE(IS_CYGWIN, 1, [1 if building for Cygwin.])
	fi
	
    AC_DEFINE(IS_WIN32, 1, [1 if building for Win32.])
    ;; 
  *-*-mingw*) 
    is_mingw=yes
    is_win32=yes

    parport_use_giveio=yes

    AC_DEFINE(IS_MINGW, 1, [1 if building for MinGW.])
    AC_DEFINE(IS_WIN32, 1, [1 if building for Win32.])
    ;; 
  *) 
	parport_use_giveio=no
    AC_DEFINE(IS_CYGWIN, 0, [0 if not building for Cygwin.])
    AC_DEFINE(IS_WIN32, 0, [0 if not building for Win32.])
    ;;
esac

if test $build_parport = yes; then
  build_bitbang=yes
  AC_DEFINE(BUILD_PARPORT, 1, [1 if you want parport.])
else
  AC_DEFINE(BUILD_PARPORT, 0, [0 if you don't want parport.])
fi

if test $build_ep93xx = yes; then
  build_bitbang=yes
  AC_DEFINE(BUILD_EP93XX, 1, [1 if you want ep93xx.])
else
  AC_DEFINE(BUILD_EP93XX, 0, [0 if you don't want ep93xx.])
fi

if test $build_at91rm9200 = yes; then
  build_bitbang=yes
  AC_DEFINE(BUILD_AT91RM9200, 1, [1 if you want at91rm9200.])
else
  AC_DEFINE(BUILD_AT91RM9200, 0, [0 if you don't want at91rm9200.])
fi

if test $parport_use_ppdev = yes; then
  AC_DEFINE(PARPORT_USE_PPDEV, 1, [1 if you want parport to use ppdev.])
else
  AC_DEFINE(PARPORT_USE_PPDEV, 0, [0 if you don't want parport to use ppdev.])
fi

if test $parport_use_giveio = yes; then
  AC_DEFINE(PARPORT_USE_GIVEIO, 1, [1 if you want parport to use giveio.])
else
  AC_DEFINE(PARPORT_USE_GIVEIO, 0, [0 if you don't want parport to use giveio.])
fi

if test $build_bitbang = yes; then
  AC_DEFINE(BUILD_BITBANG, 1, [1 if you want a bitbang interface.])
else
  AC_DEFINE(BUILD_BITBANG, 0, [0 if you don't want a bitbang interface.])
fi

if test $build_ft2232_libftdi = yes; then
  AC_DEFINE(BUILD_FT2232_LIBFTDI, 1, [1 if you want libftdi ft2232.])
else
  AC_DEFINE(BUILD_FT2232_LIBFTDI, 0, [0 if you don't want libftdi ft2232.])
fi

if test $build_ft2232_ftd2xx = yes; then
  AC_DEFINE(BUILD_FT2232_FTD2XX, 1, [1 if you want ftd2xx ft2232.])
else
  AC_DEFINE(BUILD_FT2232_FTD2XX, 0, [0 if you don't want ftd2xx ft2232.])
fi

if test $build_amtjtagaccel = yes; then
  AC_DEFINE(BUILD_AMTJTAGACCEL, 1, [1 if you want the Amontec JTAG-Accelerator driver.])
else
  AC_DEFINE(BUILD_AMTJTAGACCEL, 0, [0 if you don't want the Amontec JTAG-Accelerator driver.])
fi

if test $build_gw16012 = yes; then
  AC_DEFINE(BUILD_GW16012, 1, [1 if you want the Gateworks GW16012 driver.])
else
  AC_DEFINE(BUILD_GW16012, 0, [0 if you don't want the Gateworks GW16012 driver.])
fi

AM_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE(openocd, 0.1)

AM_CONDITIONAL(PARPORT, test $build_parport = yes)
AM_CONDITIONAL(GIVEIO, test $parport_use_giveio = yes)
AM_CONDITIONAL(EP93XX, test $build_ep93xx = yes)
AM_CONDITIONAL(AT91RM9200, test $build_at91rm9200 = yes)
AM_CONDITIONAL(BITBANG, test $build_bitbang = yes)
AM_CONDITIONAL(FT2232_LIBFTDI, test $build_ft2232_libftdi = yes)
AM_CONDITIONAL(FT2232_FTD2XX, test $build_ft2232_ftd2xx = yes)
AM_CONDITIONAL(AMTJTAGACCEL, test $build_amtjtagaccel = yes)
AM_CONDITIONAL(GW16012, test $build_gw16012 = yes)
AM_CONDITIONAL(IS_CYGWIN, test $is_cygwin = yes)
AM_CONDITIONAL(IS_MINGW, test $is_mingw = yes)
AM_CONDITIONAL(IS_WIN32, test $is_win32 = yes)
AM_CONDITIONAL(FTD2XXDIR, test $with_ftd2xx != search)

AC_LANG_C
AC_PROG_CC
AC_PROG_RANLIB

AC_SUBST(WITH_FTD2XX, $with_ftd2xx)

AC_OUTPUT(Makefile src/Makefile src/helper/Makefile src/jtag/Makefile src/xsvf/Makefile src/target/Makefile src/server/Makefile src/flash/Makefile src/pld/Makefile)